SUMIFS funtzioa

Barruti anitzetan irizpide anitz betetzen dituzten gelaxketako balioen batuketa ematen du.

tip

Funtzio hau LibreOffice bertsiotik existitzen da4.0


Sintaxia

SUMIFS(FuntzioBarrutia; Barrutia1; Irizpidea1 [ ; Barrutia2; Irizpidea2 [;...]]))

FuntzioBarrutia – derrigorrezko argumentua. Gelaxka-barruti bat, izendatutako barruti baten izen bat, edo zutabe edo errenkada baten etiketa bat da, batuketa kalkulatzeko erabiliko diren balioak dituena.

Irizpidea1 – derrigorrezko argumentua. Kate motako adierazpen bat, baldintza logiko bat edo kate-adierazpen horren gelaxka-erreferentzia bat ordezkatzen duena. Adierazpenak testua, zenbakiak, adierazpen erregularrak edo komodinak izan ditzake (kalkuluaren aukeretan gaituta badaude).

Barrutia2 – Aukerakoa. Barrutia2 eta hurrengoek Barrutia1 parametroaren esanahi bera dute.

Irizpidea2 – Aukerakoa. Irizpidea2 eta hurrengoek Irizpidea1 parametroaren esanahi bera dute.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in - LibreOffice Calc - Calculate.

warning

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".


FuntzioBarrutia eta Barrutia1,Barrutia2... parametroek tamaina bera izan behar dute, bestela funtzioak 'err:502 - Baliogabeko argumentua' errorea itzuliko du.

note

Irizpideen arteko erlazio logikoa AND logiko modura definitu daiteke. Alegia, emandako irizpide guztiak betetzen badira (eta soilik horrela bada), hartuko da kontuan kalkuluan emandako FuntzioBarrutia parametroari dagokion balio bat.


Funtzioak 255 argumentu arte izan ditzake; alegia, 127 irizpide-barruti eta irizpide zehaztu daitezke funtziorako.

Gelaxka batek TRUE (Egiazkoa) badu, 1 baliotzat hartzen du; FALSE (Gezurra) badu, 0 (zero) baliotzat.

Ohar-ikonoa

Funtzio hori Open Document Format for Office Applications (OpenDocument) estandarraren 1.2 bertsioan (ISO/IEC 26300:2-2015) dago onartuta.


Adibidea

Begiratu honako taula

A

B

C

1

Produktuaren izena

Salmentak

Diru-sarrerak

2

arkatza

20

65

3

luma

35

85

4

koadernoa

20

190

5

liburua

17

180

6

arkatz-kutxa

ez

ez


warning

Beheko adibide guztietan batuketa kalkulatzeko barrutiek #6 errenkada dute, baina hura ez ikusi egingo da testua duelako.


Erabilera sinplea

=SUMIFS(B2:B6;B2:B6;">=20")

B2:B6 barrutian 20 balioaren berdina edo handiagoak diren balioen batuketa kalkulatzen du. 75 ematen du, bosgarren errenkadak ez duelako irizpidea betetzen.

=SUMIFS(C2:C6;B2:B6;">=20";C2:C6;">70")

C2:C6 barrutian 70 baino handiagoak diren eta B2:B6 barrutian 20 balioaren berdinak edo handiagoak duten gelaxkei dagozkien balioen batuketa kalkulatzen du. 275 ematen du, bigarren eta bosgarren errenkadek ez dutelako gutxienez irizpide bat betetzen.

Adierazpen erregularrak eta habiaratutako funtzioak erabiltzea

=SUMIFS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

C2:C6 barrutian B2:B6 barrutiko balio guztiei dagozkien balioak, minimoa eta maximoa salbu, batzen ditu. 255 ematen du, hirugarren eta bosgarren errenkadek ez dutelako gutxienez irizpide bat betetzen.

=SUMIFS(C2:C6;A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

C2:C6 barrutiko balioen batuketa kalkulatzen du, "pen" katearekin hasten diren A2:A6 barrutiko gelaxkekin eta B2:B6 barrutiko gelaxka guztiekin (maximoa salbu) bat datozen balioak soilik hartuta. 65 ematen du, bigarren errenkadak soilik betetzen dituelako irizpide guztiak.

Irizpidetzat gelaxka baten erreferentzia erabiltzea

Irizpide bat erraz aldatu behar baduzu, beste gelaxka batean zehaztu dezakezu eta gelaxka horren erreferentzia bat erabili SUMIFS funtzioaren baldintzan. Adibidez, goiko funtzioa beste modu honetan idatzi daiteke:

=SUMIFS(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

E2 = pen bada, funtzioak 65 ematen du, gelaxkarako esteka bere edukiarekin ordezkatuko delako.